forked from Minki/linux
8fd63a9ea7
Currently it is possible for userspace to see the result of gettimeofday() going backwards by 1 microsecond, assuming that userspace is using the gettimeofday() in the VDSO. The VDSO gettimeofday() algorithm computes the time in "xsecs", which are units of 2^-20 seconds, or approximately 0.954 microseconds, using the algorithm now = (timebase - tb_orig_stamp) * tb_to_xs + stamp_xsec and then converts the time in xsecs to seconds and microseconds. The kernel updates the tb_orig_stamp and stamp_xsec values every tick in update_vsyscall(). If the length of the tick is not an integer number of xsecs, then some precision is lost in converting the current time to xsecs. For example, with CONFIG_HZ=1000, the tick is 1ms long, which is 1048.576 xsecs. That means that stamp_xsec will advance by either 1048 or 1049 on each tick. With the right conditions, it is possible for userspace to get (timebase - tb_orig_stamp) * tb_to_xs being 1049 if the kernel is slightly late in updating the vdso_datapage, and then for stamp_xsec to advance by 1048 when the kernel does update it, and for userspace to then see (timebase - tb_orig_stamp) * tb_to_xs being zero due to integer truncation. The result is that time appears to go backwards by 1 microsecond. To fix this we change the VDSO gettimeofday to use a new field in the VDSO datapage which stores the nanoseconds part of the time as a fractional number of seconds in a 0.32 binary fraction format. (Or put another way, as a 32-bit number in units of 0.23283 ns.) This is convenient because we can use the mulhwu instruction to convert it to either microseconds or nanoseconds. Since it turns out that computing the time of day using this new field is simpler than either using stamp_xsec (as gettimeofday does) or stamp_xtime.tv_nsec (as clock_gettime does), this converts both gettimeofday and clock_gettime to use the new field. The existing __do_get_tspec function is converted to use the new field and take a parameter in r7 that indicates the desired resolution, 1,000,000 for microseconds or 1,000,000,000 for nanoseconds. The __do_get_xsec function is then unused and is deleted. The new algorithm is now = ((timebase - tb_orig_stamp) << 12) * tb_to_xs + (stamp_xtime_seconds << 32) + stamp_sec_fraction with 'now' in units of 2^-32 seconds. That is then converted to seconds and either microseconds or nanoseconds with seconds = now >> 32 partseconds = ((now & 0xffffffff) * resolution) >> 32 The 32-bit VDSO code also makes a further simplification: it ignores the bottom 32 bits of the tb_to_xs value, which is a 0.64 format binary fraction. Doing so gets rid of 4 multiply instructions. Assuming a timebase frequency of 1GHz or less and an update interval of no more than 10ms, the upper 32 bits of tb_to_xs will be at least 4503599, so the error from ignoring the low 32 bits will be at most 2.2ns, which is more than an order of magnitude less than the time taken to do gettimeofday or clock_gettime on our fastest processors, so there is no possibility of seeing inconsistent values due to this. This also moves update_gtod() down next to its only caller, and makes update_vsyscall use the time passed in via the wall_time argument rather than accessing xtime directly. At present, wall_time always points to xtime, but that could change in future. Signed-off-by: Paul Mackerras <paulus@samba.org> Signed-off-by: Benjamin Herrenschmidt <benh@kernel.crashing.org>
219 lines
5.2 KiB
ArmAsm
219 lines
5.2 KiB
ArmAsm
/*
|
|
* Userland implementation of gettimeofday() for 64 bits processes in a
|
|
* ppc64 kernel for use in the vDSO
|
|
*
|
|
* Copyright (C) 2004 Benjamin Herrenschmuidt (benh@kernel.crashing.org),
|
|
* IBM Corp.
|
|
*
|
|
* This program is free software; you can redistribute it and/or
|
|
* modify it under the terms of the GNU General Public License
|
|
* as published by the Free Software Foundation; either version
|
|
* 2 of the License, or (at your option) any later version.
|
|
*/
|
|
#include <asm/processor.h>
|
|
#include <asm/ppc_asm.h>
|
|
#include <asm/vdso.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/unistd.h>
|
|
|
|
.text
|
|
/*
|
|
* Exact prototype of gettimeofday
|
|
*
|
|
* int __kernel_gettimeofday(struct timeval *tv, struct timezone *tz);
|
|
*
|
|
*/
|
|
V_FUNCTION_BEGIN(__kernel_gettimeofday)
|
|
.cfi_startproc
|
|
mflr r12
|
|
.cfi_register lr,r12
|
|
|
|
mr r11,r3 /* r11 holds tv */
|
|
mr r10,r4 /* r10 holds tz */
|
|
bl V_LOCAL_FUNC(__get_datapage) /* get data page */
|
|
cmpldi r11,0 /* check if tv is NULL */
|
|
beq 2f
|
|
lis r7,1000000@ha /* load up USEC_PER_SEC */
|
|
addi r7,r7,1000000@l
|
|
bl V_LOCAL_FUNC(__do_get_tspec) /* get sec/us from tb & kernel */
|
|
std r4,TVAL64_TV_SEC(r11) /* store sec in tv */
|
|
std r5,TVAL64_TV_USEC(r11) /* store usec in tv */
|
|
2: cmpldi r10,0 /* check if tz is NULL */
|
|
beq 1f
|
|
lwz r4,CFG_TZ_MINUTEWEST(r3)/* fill tz */
|
|
lwz r5,CFG_TZ_DSTTIME(r3)
|
|
stw r4,TZONE_TZ_MINWEST(r10)
|
|
stw r5,TZONE_TZ_DSTTIME(r10)
|
|
1: mtlr r12
|
|
crclr cr0*4+so
|
|
li r3,0 /* always success */
|
|
blr
|
|
.cfi_endproc
|
|
V_FUNCTION_END(__kernel_gettimeofday)
|
|
|
|
|
|
/*
|
|
* Exact prototype of clock_gettime()
|
|
*
|
|
* int __kernel_clock_gettime(clockid_t clock_id, struct timespec *tp);
|
|
*
|
|
*/
|
|
V_FUNCTION_BEGIN(__kernel_clock_gettime)
|
|
.cfi_startproc
|
|
/* Check for supported clock IDs */
|
|
cmpwi cr0,r3,CLOCK_REALTIME
|
|
cmpwi cr1,r3,CLOCK_MONOTONIC
|
|
cror cr0*4+eq,cr0*4+eq,cr1*4+eq
|
|
bne cr0,99f
|
|
|
|
mflr r12 /* r12 saves lr */
|
|
.cfi_register lr,r12
|
|
mr r11,r4 /* r11 saves tp */
|
|
bl V_LOCAL_FUNC(__get_datapage) /* get data page */
|
|
lis r7,NSEC_PER_SEC@h /* want nanoseconds */
|
|
ori r7,r7,NSEC_PER_SEC@l
|
|
50: bl V_LOCAL_FUNC(__do_get_tspec) /* get time from tb & kernel */
|
|
bne cr1,80f /* if not monotonic, all done */
|
|
|
|
/*
|
|
* CLOCK_MONOTONIC
|
|
*/
|
|
|
|
/* now we must fixup using wall to monotonic. We need to snapshot
|
|
* that value and do the counter trick again. Fortunately, we still
|
|
* have the counter value in r8 that was returned by __do_get_tspec.
|
|
* At this point, r4,r5 contain our sec/nsec values.
|
|
*/
|
|
|
|
lwa r6,WTOM_CLOCK_SEC(r3)
|
|
lwa r9,WTOM_CLOCK_NSEC(r3)
|
|
|
|
/* We now have our result in r6,r9. We create a fake dependency
|
|
* on that result and re-check the counter
|
|
*/
|
|
or r0,r6,r9
|
|
xor r0,r0,r0
|
|
add r3,r3,r0
|
|
ld r0,CFG_TB_UPDATE_COUNT(r3)
|
|
cmpld cr0,r0,r8 /* check if updated */
|
|
bne- 50b
|
|
|
|
/* Add wall->monotonic offset and check for overflow or underflow.
|
|
*/
|
|
add r4,r4,r6
|
|
add r5,r5,r9
|
|
cmpd cr0,r5,r7
|
|
cmpdi cr1,r5,0
|
|
blt 1f
|
|
subf r5,r7,r5
|
|
addi r4,r4,1
|
|
1: bge cr1,80f
|
|
addi r4,r4,-1
|
|
add r5,r5,r7
|
|
|
|
80: std r4,TSPC64_TV_SEC(r11)
|
|
std r5,TSPC64_TV_NSEC(r11)
|
|
|
|
mtlr r12
|
|
crclr cr0*4+so
|
|
li r3,0
|
|
blr
|
|
|
|
/*
|
|
* syscall fallback
|
|
*/
|
|
99:
|
|
li r0,__NR_clock_gettime
|
|
sc
|
|
blr
|
|
.cfi_endproc
|
|
V_FUNCTION_END(__kernel_clock_gettime)
|
|
|
|
|
|
/*
|
|
* Exact prototype of clock_getres()
|
|
*
|
|
* int __kernel_clock_getres(clockid_t clock_id, struct timespec *res);
|
|
*
|
|
*/
|
|
V_FUNCTION_BEGIN(__kernel_clock_getres)
|
|
.cfi_startproc
|
|
/* Check for supported clock IDs */
|
|
cmpwi cr0,r3,CLOCK_REALTIME
|
|
cmpwi cr1,r3,CLOCK_MONOTONIC
|
|
cror cr0*4+eq,cr0*4+eq,cr1*4+eq
|
|
bne cr0,99f
|
|
|
|
li r3,0
|
|
cmpli cr0,r4,0
|
|
crclr cr0*4+so
|
|
beqlr
|
|
lis r5,CLOCK_REALTIME_RES@h
|
|
ori r5,r5,CLOCK_REALTIME_RES@l
|
|
std r3,TSPC64_TV_SEC(r4)
|
|
std r5,TSPC64_TV_NSEC(r4)
|
|
blr
|
|
|
|
/*
|
|
* syscall fallback
|
|
*/
|
|
99:
|
|
li r0,__NR_clock_getres
|
|
sc
|
|
blr
|
|
.cfi_endproc
|
|
V_FUNCTION_END(__kernel_clock_getres)
|
|
|
|
|
|
/*
|
|
* This is the core of clock_gettime() and gettimeofday(),
|
|
* it returns the current time in r4 (seconds) and r5.
|
|
* On entry, r7 gives the resolution of r5, either USEC_PER_SEC
|
|
* or NSEC_PER_SEC, giving r5 in microseconds or nanoseconds.
|
|
* It expects the datapage ptr in r3 and doesn't clobber it.
|
|
* It clobbers r0, r6 and r9.
|
|
* On return, r8 contains the counter value that can be reused.
|
|
* This clobbers cr0 but not any other cr field.
|
|
*/
|
|
V_FUNCTION_BEGIN(__do_get_tspec)
|
|
.cfi_startproc
|
|
/* check for update count & load values */
|
|
1: ld r8,CFG_TB_UPDATE_COUNT(r3)
|
|
andi. r0,r8,1 /* pending update ? loop */
|
|
bne- 1b
|
|
xor r0,r8,r8 /* create dependency */
|
|
add r3,r3,r0
|
|
|
|
/* Get TB & offset it. We use the MFTB macro which will generate
|
|
* workaround code for Cell.
|
|
*/
|
|
MFTB(r6)
|
|
ld r9,CFG_TB_ORIG_STAMP(r3)
|
|
subf r6,r9,r6
|
|
|
|
/* Scale result */
|
|
ld r5,CFG_TB_TO_XS(r3)
|
|
sldi r6,r6,12 /* compute time since stamp_xtime */
|
|
mulhdu r6,r6,r5 /* in units of 2^-32 seconds */
|
|
|
|
/* Add stamp since epoch */
|
|
ld r4,STAMP_XTIME+TSPC64_TV_SEC(r3)
|
|
lwz r5,STAMP_SEC_FRAC(r3)
|
|
or r0,r4,r5
|
|
or r0,r0,r6
|
|
xor r0,r0,r0
|
|
add r3,r3,r0
|
|
ld r0,CFG_TB_UPDATE_COUNT(r3)
|
|
cmpld r0,r8 /* check if updated */
|
|
bne- 1b /* reload if so */
|
|
|
|
/* convert to seconds & nanoseconds and add to stamp */
|
|
add r6,r6,r5 /* add on fractional seconds of xtime */
|
|
mulhwu r5,r6,r7 /* compute micro or nanoseconds and */
|
|
srdi r6,r6,32 /* seconds since stamp_xtime */
|
|
clrldi r5,r5,32
|
|
add r4,r4,r6
|
|
blr
|
|
.cfi_endproc
|
|
V_FUNCTION_END(__do_get_tspec)
|