mirror of
https://github.com/godotengine/godot.git
synced 2024-11-22 04:06:14 +00:00
c7b53c03ae
Since we clone the environments to build thirdparty code, we don't get an explicit dependency on the build objects produced by that environment. So when we update thirdparty code, Godot code using it is not necessarily rebuilt (I think it is for changed headers, but not for changed .c/.cpp files), which can lead to an invalid compilation output (linking old Godot .o files with a newer, potentially ABI breaking version of thirdparty code). This was only seen as really problematic with bullet updates (leading to crashes when rebuilding Godot after a bullet update without cleaning .o files), but it's safer to fix it everywhere, even if it's a LOT of hacky boilerplate.
44 lines
1015 B
Python
44 lines
1015 B
Python
#!/usr/bin/env python
|
|
|
|
Import("env")
|
|
Import("env_modules")
|
|
|
|
env_enet = env_modules.Clone()
|
|
|
|
# Thirdparty source files
|
|
|
|
thirdparty_obj = []
|
|
|
|
if env["builtin_enet"]:
|
|
thirdparty_dir = "#thirdparty/enet/"
|
|
thirdparty_sources = [
|
|
"godot.cpp",
|
|
"callbacks.c",
|
|
"compress.c",
|
|
"host.c",
|
|
"list.c",
|
|
"packet.c",
|
|
"peer.c",
|
|
"protocol.c",
|
|
]
|
|
thirdparty_sources = [thirdparty_dir + file for file in thirdparty_sources]
|
|
|
|
env_enet.Prepend(CPPPATH=[thirdparty_dir])
|
|
env_enet.Append(CPPDEFINES=["GODOT_ENET"])
|
|
|
|
env_thirdparty = env_enet.Clone()
|
|
env_thirdparty.disable_warnings()
|
|
env_thirdparty.add_source_files(thirdparty_obj, thirdparty_sources)
|
|
env.modules_sources += thirdparty_obj
|
|
|
|
|
|
# Godot source files
|
|
|
|
module_obj = []
|
|
|
|
env_enet.add_source_files(module_obj, "*.cpp")
|
|
env.modules_sources += module_obj
|
|
|
|
# Needed to force rebuilding the module files when the thirdparty library is updated.
|
|
env.Depends(module_obj, thirdparty_obj)
|