mirror of
https://github.com/godotengine/godot.git
synced 2024-11-25 13:43:15 +00:00
8de6405288
The UWP platform port was never ported to the Godot 4.0+ API, and it's now accumulating bitrot as it doesn't compile, and thus we no longer propagate platform changes in it. So we finally remove to acknowledge this state. There's still some interest in reviving the UWP port eventually, especially as support for Direct3D 12 will soon be merged, but when that happens it will be easiest to redo it from scratch.
50 lines
1.3 KiB
Python
50 lines
1.3 KiB
Python
#!/usr/bin/env python
|
|
|
|
Import("env")
|
|
Import("env_modules")
|
|
|
|
env_ws = env_modules.Clone()
|
|
|
|
thirdparty_obj = []
|
|
|
|
if env["platform"] == "web":
|
|
# Our JavaScript/C++ interface.
|
|
env.AddJSLibraries(["library_godot_websocket.js"])
|
|
|
|
elif env["builtin_wslay"]:
|
|
# Thirdparty source files
|
|
thirdparty_dir = "#thirdparty/wslay/"
|
|
thirdparty_sources = [
|
|
"wslay_net.c",
|
|
"wslay_event.c",
|
|
"wslay_queue.c",
|
|
"wslay_frame.c",
|
|
]
|
|
thirdparty_sources = [thirdparty_dir + s for s in thirdparty_sources]
|
|
|
|
env_ws.Prepend(CPPPATH=[thirdparty_dir])
|
|
env_ws.Append(CPPDEFINES=["HAVE_CONFIG_H"])
|
|
|
|
if env["platform"] == "windows":
|
|
env_ws.Append(CPPDEFINES=["HAVE_WINSOCK2_H"])
|
|
else:
|
|
env_ws.Append(CPPDEFINES=["HAVE_NETINET_IN_H"])
|
|
|
|
env_thirdparty = env_ws.Clone()
|
|
env_thirdparty.disable_warnings()
|
|
env_thirdparty.add_source_files(thirdparty_obj, thirdparty_sources)
|
|
env.modules_sources += thirdparty_obj
|
|
|
|
|
|
# Godot source files
|
|
|
|
module_obj = []
|
|
|
|
env_ws.add_source_files(module_obj, "*.cpp")
|
|
if env.editor_build:
|
|
env_ws.add_source_files(module_obj, "editor/*.cpp")
|
|
env.modules_sources += module_obj
|
|
|
|
# Needed to force rebuilding the module files when the thirdparty library is updated.
|
|
env.Depends(module_obj, thirdparty_obj)
|