ghidra/Ghidra/RuntimeScripts/build.gradle

/* ###
 * IP: GHIDRA
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
apply plugin: 'eclipse'

eclipse.project.name = '_Runtime Scripts'

rootProject.assembleDistribution {

	from (this.project.file("Common/support")) {
		into "support"
	}
	
	from (this.project.file("Common/server")) {
		into "server"
	}
}

rootProject.PLATFORMS.each { platform ->
	rootProject.tasks.findAll {it.name == "assembleDistribution_${platform.name}"}.each { t -> 
		def p = this.project

		if (isLinux(platform.name) || isMac(platform.name)) {
			t.from ("${p.projectDir}/Linux/support") {
				into "support"
			}
			t.from ("${p.projectDir}/Linux/server") {
				into "server"
			}
			t.from ("${rootProject.projectDir}") {
				include "gradlew"
				into "support/gradle"
			}
			t.from (p.file("Linux/ghidraRun"))
		}

		if (isWindows(platform.name)) {
			t.from ("${p.projectDir}/Windows/support") {
				into "support"
			}
			t.from ("${p.projectDir}/Windows/server") {
				into "server"
			}
			t.from ("${rootProject.projectDir}") {
				include "gradlew.bat"
				into "support/gradle"
			}
			t.from (p.file("Windows/ghidraRun.bat"))
		}
	}
}