mirror of
https://github.com/torvalds/linux.git
synced 2024-12-12 14:12:51 +00:00
090a3f6155
... instead of the semi-version with the spelled out sections. What is more, make the REP_GOOD version be the default copy_page() version as the majority of the relevant x86 CPUs do set X86_FEATURE_REP_GOOD. Thus, copy_page gets compiled to: ffffffff8130af80 <copy_page>: ffffffff8130af80: e9 0b 00 00 00 jmpq ffffffff8130af90 <copy_page_regs> ffffffff8130af85: b9 00 02 00 00 mov $0x200,%ecx ffffffff8130af8a: f3 48 a5 rep movsq %ds:(%rsi),%es:(%rdi) ffffffff8130af8d: c3 retq ffffffff8130af8e: 66 90 xchg %ax,%ax ffffffff8130af90 <copy_page_regs>: ... and after the alternatives have run, the JMP to the old, unrolled version gets NOPed out: ffffffff8130af80 <copy_page>: ffffffff8130af80: 66 66 90 xchg %ax,%ax ffffffff8130af83: 66 90 xchg %ax,%ax ffffffff8130af85: b9 00 02 00 00 mov $0x200,%ecx ffffffff8130af8a: f3 48 a5 rep movsq %ds:(%rsi),%es:(%rdi) ffffffff8130af8d: c3 retq On modern uarches, those NOPs are cheaper than the unconditional JMP previously. Signed-off-by: Borislav Petkov <bp@suse.de>
98 lines
1.9 KiB
ArmAsm
98 lines
1.9 KiB
ArmAsm
/* Written 2003 by Andi Kleen, based on a kernel by Evandro Menezes */
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/dwarf2.h>
|
|
#include <asm/cpufeature.h>
|
|
#include <asm/alternative-asm.h>
|
|
|
|
/*
|
|
* Some CPUs run faster using the string copy instructions (sane microcode).
|
|
* It is also a lot simpler. Use this when possible. But, don't use streaming
|
|
* copy unless the CPU indicates X86_FEATURE_REP_GOOD. Could vary the
|
|
* prefetch distance based on SMP/UP.
|
|
*/
|
|
ALIGN
|
|
ENTRY(copy_page)
|
|
CFI_STARTPROC
|
|
ALTERNATIVE "jmp copy_page_regs", "", X86_FEATURE_REP_GOOD
|
|
movl $4096/8, %ecx
|
|
rep movsq
|
|
ret
|
|
CFI_ENDPROC
|
|
ENDPROC(copy_page)
|
|
|
|
ENTRY(copy_page_regs)
|
|
CFI_STARTPROC
|
|
subq $2*8, %rsp
|
|
CFI_ADJUST_CFA_OFFSET 2*8
|
|
movq %rbx, (%rsp)
|
|
CFI_REL_OFFSET rbx, 0
|
|
movq %r12, 1*8(%rsp)
|
|
CFI_REL_OFFSET r12, 1*8
|
|
|
|
movl $(4096/64)-5, %ecx
|
|
.p2align 4
|
|
.Loop64:
|
|
dec %rcx
|
|
movq 0x8*0(%rsi), %rax
|
|
movq 0x8*1(%rsi), %rbx
|
|
movq 0x8*2(%rsi), %rdx
|
|
movq 0x8*3(%rsi), %r8
|
|
movq 0x8*4(%rsi), %r9
|
|
movq 0x8*5(%rsi), %r10
|
|
movq 0x8*6(%rsi), %r11
|
|
movq 0x8*7(%rsi), %r12
|
|
|
|
prefetcht0 5*64(%rsi)
|
|
|
|
movq %rax, 0x8*0(%rdi)
|
|
movq %rbx, 0x8*1(%rdi)
|
|
movq %rdx, 0x8*2(%rdi)
|
|
movq %r8, 0x8*3(%rdi)
|
|
movq %r9, 0x8*4(%rdi)
|
|
movq %r10, 0x8*5(%rdi)
|
|
movq %r11, 0x8*6(%rdi)
|
|
movq %r12, 0x8*7(%rdi)
|
|
|
|
leaq 64 (%rsi), %rsi
|
|
leaq 64 (%rdi), %rdi
|
|
|
|
jnz .Loop64
|
|
|
|
movl $5, %ecx
|
|
.p2align 4
|
|
.Loop2:
|
|
decl %ecx
|
|
|
|
movq 0x8*0(%rsi), %rax
|
|
movq 0x8*1(%rsi), %rbx
|
|
movq 0x8*2(%rsi), %rdx
|
|
movq 0x8*3(%rsi), %r8
|
|
movq 0x8*4(%rsi), %r9
|
|
movq 0x8*5(%rsi), %r10
|
|
movq 0x8*6(%rsi), %r11
|
|
movq 0x8*7(%rsi), %r12
|
|
|
|
movq %rax, 0x8*0(%rdi)
|
|
movq %rbx, 0x8*1(%rdi)
|
|
movq %rdx, 0x8*2(%rdi)
|
|
movq %r8, 0x8*3(%rdi)
|
|
movq %r9, 0x8*4(%rdi)
|
|
movq %r10, 0x8*5(%rdi)
|
|
movq %r11, 0x8*6(%rdi)
|
|
movq %r12, 0x8*7(%rdi)
|
|
|
|
leaq 64(%rdi), %rdi
|
|
leaq 64(%rsi), %rsi
|
|
jnz .Loop2
|
|
|
|
movq (%rsp), %rbx
|
|
CFI_RESTORE rbx
|
|
movq 1*8(%rsp), %r12
|
|
CFI_RESTORE r12
|
|
addq $2*8, %rsp
|
|
CFI_ADJUST_CFA_OFFSET -2*8
|
|
ret
|
|
CFI_ENDPROC
|
|
ENDPROC(copy_page_regs)
|