mirror of
https://github.com/torvalds/linux.git
synced 2024-12-27 05:11:48 +00:00
6038f373a3
All file_operations should get a .llseek operation so we can make
nonseekable_open the default for future file operations without a
.llseek pointer.
The three cases that we can automatically detect are no_llseek, seq_lseek
and default_llseek. For cases where we can we can automatically prove that
the file offset is always ignored, we use noop_llseek, which maintains
the current behavior of not returning an error from a seek.
New drivers should normally not use noop_llseek but instead use no_llseek
and call nonseekable_open at open time. Existing drivers can be converted
to do the same when the maintainer knows for certain that no user code
relies on calling seek on the device file.
The generated code is often incorrectly indented and right now contains
comments that clarify for each added line why a specific variant was
chosen. In the version that gets submitted upstream, the comments will
be gone and I will manually fix the indentation, because there does not
seem to be a way to do that using coccinelle.
Some amount of new code is currently sitting in linux-next that should get
the same modifications, which I will do at the end of the merge window.
Many thanks to Julia Lawall for helping me learn to write a semantic
patch that does all this.
===== begin semantic patch =====
// This adds an llseek= method to all file operations,
// as a preparation for making no_llseek the default.
//
// The rules are
// - use no_llseek explicitly if we do nonseekable_open
// - use seq_lseek for sequential files
// - use default_llseek if we know we access f_pos
// - use noop_llseek if we know we don't access f_pos,
// but we still want to allow users to call lseek
//
@ open1 exists @
identifier nested_open;
@@
nested_open(...)
{
<+...
nonseekable_open(...)
...+>
}
@ open exists@
identifier open_f;
identifier i, f;
identifier open1.nested_open;
@@
int open_f(struct inode *i, struct file *f)
{
<+...
(
nonseekable_open(...)
|
nested_open(...)
)
...+>
}
@ read disable optional_qualifier exists @
identifier read_f;
identifier f, p, s, off;
type ssize_t, size_t, loff_t;
expression E;
identifier func;
@@
ssize_t read_f(struct file *f, char *p, size_t s, loff_t *off)
{
<+...
(
*off = E
|
*off += E
|
func(..., off, ...)
|
E = *off
)
...+>
}
@ read_no_fpos disable optional_qualifier exists @
identifier read_f;
identifier f, p, s, off;
type ssize_t, size_t, loff_t;
@@
ssize_t read_f(struct file *f, char *p, size_t s, loff_t *off)
{
... when != off
}
@ write @
identifier write_f;
identifier f, p, s, off;
type ssize_t, size_t, loff_t;
expression E;
identifier func;
@@
ssize_t write_f(struct file *f, const char *p, size_t s, loff_t *off)
{
<+...
(
*off = E
|
*off += E
|
func(..., off, ...)
|
E = *off
)
...+>
}
@ write_no_fpos @
identifier write_f;
identifier f, p, s, off;
type ssize_t, size_t, loff_t;
@@
ssize_t write_f(struct file *f, const char *p, size_t s, loff_t *off)
{
... when != off
}
@ fops0 @
identifier fops;
@@
struct file_operations fops = {
...
};
@ has_llseek depends on fops0 @
identifier fops0.fops;
identifier llseek_f;
@@
struct file_operations fops = {
...
.llseek = llseek_f,
...
};
@ has_read depends on fops0 @
identifier fops0.fops;
identifier read_f;
@@
struct file_operations fops = {
...
.read = read_f,
...
};
@ has_write depends on fops0 @
identifier fops0.fops;
identifier write_f;
@@
struct file_operations fops = {
...
.write = write_f,
...
};
@ has_open depends on fops0 @
identifier fops0.fops;
identifier open_f;
@@
struct file_operations fops = {
...
.open = open_f,
...
};
// use no_llseek if we call nonseekable_open
////////////////////////////////////////////
@ nonseekable1 depends on !has_llseek && has_open @
identifier fops0.fops;
identifier nso ~= "nonseekable_open";
@@
struct file_operations fops = {
... .open = nso, ...
+.llseek = no_llseek, /* nonseekable */
};
@ nonseekable2 depends on !has_llseek @
identifier fops0.fops;
identifier open.open_f;
@@
struct file_operations fops = {
... .open = open_f, ...
+.llseek = no_llseek, /* open uses nonseekable */
};
// use seq_lseek for sequential files
/////////////////////////////////////
@ seq depends on !has_llseek @
identifier fops0.fops;
identifier sr ~= "seq_read";
@@
struct file_operations fops = {
... .read = sr, ...
+.llseek = seq_lseek, /* we have seq_read */
};
// use default_llseek if there is a readdir
///////////////////////////////////////////
@ fops1 depends on !has_llseek && !nonseekable1 && !nonseekable2 && !seq @
identifier fops0.fops;
identifier readdir_e;
@@
// any other fop is used that changes pos
struct file_operations fops = {
... .readdir = readdir_e, ...
+.llseek = default_llseek, /* readdir is present */
};
// use default_llseek if at least one of read/write touches f_pos
/////////////////////////////////////////////////////////////////
@ fops2 depends on !fops1 && !has_llseek && !nonseekable1 && !nonseekable2 && !seq @
identifier fops0.fops;
identifier read.read_f;
@@
// read fops use offset
struct file_operations fops = {
... .read = read_f, ...
+.llseek = default_llseek, /* read accesses f_pos */
};
@ fops3 depends on !fops1 && !fops2 && !has_llseek && !nonseekable1 && !nonseekable2 && !seq @
identifier fops0.fops;
identifier write.write_f;
@@
// write fops use offset
struct file_operations fops = {
... .write = write_f, ...
+ .llseek = default_llseek, /* write accesses f_pos */
};
// Use noop_llseek if neither read nor write accesses f_pos
///////////////////////////////////////////////////////////
@ fops4 depends on !fops1 && !fops2 && !fops3 && !has_llseek && !nonseekable1 && !nonseekable2 && !seq @
identifier fops0.fops;
identifier read_no_fpos.read_f;
identifier write_no_fpos.write_f;
@@
// write fops use offset
struct file_operations fops = {
...
.write = write_f,
.read = read_f,
...
+.llseek = noop_llseek, /* read and write both use no f_pos */
};
@ depends on has_write && !has_read && !fops1 && !fops2 && !has_llseek && !nonseekable1 && !nonseekable2 && !seq @
identifier fops0.fops;
identifier write_no_fpos.write_f;
@@
struct file_operations fops = {
... .write = write_f, ...
+.llseek = noop_llseek, /* write uses no f_pos */
};
@ depends on has_read && !has_write && !fops1 && !fops2 && !has_llseek && !nonseekable1 && !nonseekable2 && !seq @
identifier fops0.fops;
identifier read_no_fpos.read_f;
@@
struct file_operations fops = {
... .read = read_f, ...
+.llseek = noop_llseek, /* read uses no f_pos */
};
@ depends on !has_read && !has_write && !fops1 && !fops2 && !has_llseek && !nonseekable1 && !nonseekable2 && !seq @
identifier fops0.fops;
@@
struct file_operations fops = {
...
+.llseek = noop_llseek, /* no read or write fn */
};
===== End semantic patch =====
Signed-off-by: Arnd Bergmann <arnd@arndb.de>
Cc: Julia Lawall <julia@diku.dk>
Cc: Christoph Hellwig <hch@infradead.org>
|
||
|---|---|---|
| .. | ||
| aty | ||
| backlight | ||
| console | ||
| display | ||
| geode | ||
| i810 | ||
| intelfb | ||
| kyro | ||
| logo | ||
| matrox | ||
| mb862xx | ||
| mbx | ||
| msm | ||
| nvidia | ||
| omap | ||
| omap2 | ||
| pnx4008 | ||
| riva | ||
| savage | ||
| sis | ||
| vermilion | ||
| via | ||
| 68328fb.c | ||
| acornfb.c | ||
| acornfb.h | ||
| amba-clcd.c | ||
| amifb.c | ||
| arcfb.c | ||
| arkfb.c | ||
| asiliantfb.c | ||
| atafb_iplan2p2.c | ||
| atafb_iplan2p4.c | ||
| atafb_iplan2p8.c | ||
| atafb_mfb.c | ||
| atafb_utils.h | ||
| atafb.c | ||
| atafb.h | ||
| atmel_lcdfb.c | ||
| au1100fb.c | ||
| au1100fb.h | ||
| au1200fb.c | ||
| au1200fb.h | ||
| bf54x-lq043fb.c | ||
| bfin-lq035q1-fb.c | ||
| bfin-t350mcqb-fb.c | ||
| broadsheetfb.c | ||
| bt431.h | ||
| bt455.h | ||
| bw2.c | ||
| c2p_core.h | ||
| c2p_iplan2.c | ||
| c2p_planar.c | ||
| c2p.h | ||
| carminefb_regs.h | ||
| carminefb.c | ||
| carminefb.h | ||
| cfbcopyarea.c | ||
| cfbfillrect.c | ||
| cfbimgblt.c | ||
| cg3.c | ||
| cg6.c | ||
| cg14.c | ||
| chipsfb.c | ||
| cirrusfb.c | ||
| clps711xfb.c | ||
| cobalt_lcdfb.c | ||
| controlfb.c | ||
| controlfb.h | ||
| cyber2000fb.c | ||
| cyber2000fb.h | ||
| da8xx-fb.c | ||
| dnfb.c | ||
| edid.h | ||
| efifb.c | ||
| ep93xx-fb.c | ||
| epson1355fb.c | ||
| fb_ddc.c | ||
| fb_defio.c | ||
| fb_draw.h | ||
| fb_notify.c | ||
| fb_sys_fops.c | ||
| fbcmap.c | ||
| fbcvt.c | ||
| fbmem.c | ||
| fbmon.c | ||
| fbsysfs.c | ||
| ffb.c | ||
| fm2fb.c | ||
| fsl-diu-fb.c | ||
| g364fb.c | ||
| gbefb.c | ||
| gxt4500.c | ||
| hecubafb.c | ||
| hgafb.c | ||
| hitfb.c | ||
| hpfb.c | ||
| igafb.c | ||
| imsttfb.c | ||
| imxfb.c | ||
| jz4740_fb.c | ||
| Kconfig | ||
| leo.c | ||
| macfb.c | ||
| macmodes.c | ||
| macmodes.h | ||
| Makefile | ||
| maxinefb.c | ||
| metronomefb.c | ||
| modedb.c | ||
| mx3fb.c | ||
| n411.c | ||
| neofb.c | ||
| nuc900fb.c | ||
| nuc900fb.h | ||
| offb.c | ||
| output.c | ||
| p9100.c | ||
| platinumfb.c | ||
| platinumfb.h | ||
| pm2fb.c | ||
| pm3fb.c | ||
| pmag-aa-fb.c | ||
| pmag-ba-fb.c | ||
| pmagb-b-fb.c | ||
| ps3fb.c | ||
| pvr2fb.c | ||
| pxa168fb.c | ||
| pxa168fb.h | ||
| pxafb.c | ||
| pxafb.h | ||
| q40fb.c | ||
| s1d13xxxfb.c | ||
| s3c2410fb.c | ||
| s3c2410fb.h | ||
| s3c-fb.c | ||
| s3fb.c | ||
| sa1100fb.c | ||
| sa1100fb.h | ||
| sbuslib.c | ||
| sbuslib.h | ||
| sgivwfb.c | ||
| sh7760fb.c | ||
| sh_mipi_dsi.c | ||
| sh_mobile_hdmi.c | ||
| sh_mobile_lcdcfb.c | ||
| skeletonfb.c | ||
| sm501fb.c | ||
| sstfb.c | ||
| sticore.h | ||
| stifb.c | ||
| sunxvr500.c | ||
| sunxvr1000.c | ||
| sunxvr2500.c | ||
| svgalib.c | ||
| syscopyarea.c | ||
| sysfillrect.c | ||
| sysimgblt.c | ||
| tcx.c | ||
| tdfxfb.c | ||
| tgafb.c | ||
| tmiofb.c | ||
| tridentfb.c | ||
| uvesafb.c | ||
| valkyriefb.c | ||
| valkyriefb.h | ||
| vesafb.c | ||
| vfb.c | ||
| vga16fb.c | ||
| vgastate.c | ||
| vt8623fb.c | ||
| w100fb.c | ||
| w100fb.h | ||
| xen-fbfront.c | ||
| xilinxfb.c | ||