mirror of
https://github.com/torvalds/linux.git
synced 2024-12-23 11:21:33 +00:00
6ebbf2ce43
ARMv6 and greater introduced a new instruction ("bx") which can be used
to return from function calls. Recent CPUs perform better when the
"bx lr" instruction is used rather than the "mov pc, lr" instruction,
and this sequence is strongly recommended to be used by the ARM
architecture manual (section A.4.1.1).
We provide a new macro "ret" with all its variants for the condition
code which will resolve to the appropriate instruction.
Rather than doing this piecemeal, and miss some instances, change all
the "mov pc" instances to use the new macro, with the exception of
the "movs" instruction and the kprobes code. This allows us to detect
the "mov pc, lr" case and fix it up - and also gives us the possibility
of deploying this for other registers depending on the CPU selection.
Reported-by: Will Deacon <will.deacon@arm.com>
Tested-by: Stephen Warren <swarren@nvidia.com> # Tegra Jetson TK1
Tested-by: Robert Jarzmik <robert.jarzmik@free.fr> # mioa701_bootresume.S
Tested-by: Andrew Lunn <andrew@lunn.ch> # Kirkwood
Tested-by: Shawn Guo <shawn.guo@freescale.com>
Tested-by: Tony Lindgren <tony@atomide.com> # OMAPs
Tested-by: Gregory CLEMENT <gregory.clement@free-electrons.com> # Armada XP, 375, 385
Acked-by: Sekhar Nori <nsekhar@ti.com> # DaVinci
Acked-by: Christoffer Dall <christoffer.dall@linaro.org> # kvm/hyp
Acked-by: Haojian Zhuang <haojian.zhuang@gmail.com> # PXA3xx
Acked-by: Stefano Stabellini <stefano.stabellini@eu.citrix.com> # Xen
Tested-by: Uwe Kleine-König <u.kleine-koenig@pengutronix.de> # ARMv7M
Tested-by: Simon Horman <horms+renesas@verge.net.au> # Shmobile
Signed-off-by: Russell King <rmk+kernel@arm.linux.org.uk>
80 lines
1.5 KiB
ArmAsm
80 lines
1.5 KiB
ArmAsm
/*
|
|
* linux/arch/arm/lib/io-readsl.S
|
|
*
|
|
* Copyright (C) 1995-2000 Russell King
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <asm/assembler.h>
|
|
|
|
ENTRY(__raw_readsl)
|
|
teq r2, #0 @ do we have to check for the zero len?
|
|
reteq lr
|
|
ands ip, r1, #3
|
|
bne 3f
|
|
|
|
subs r2, r2, #4
|
|
bmi 2f
|
|
stmfd sp!, {r4, lr}
|
|
1: ldr r3, [r0, #0]
|
|
ldr r4, [r0, #0]
|
|
ldr ip, [r0, #0]
|
|
ldr lr, [r0, #0]
|
|
subs r2, r2, #4
|
|
stmia r1!, {r3, r4, ip, lr}
|
|
bpl 1b
|
|
ldmfd sp!, {r4, lr}
|
|
2: movs r2, r2, lsl #31
|
|
ldrcs r3, [r0, #0]
|
|
ldrcs ip, [r0, #0]
|
|
stmcsia r1!, {r3, ip}
|
|
ldrne r3, [r0, #0]
|
|
strne r3, [r1, #0]
|
|
ret lr
|
|
|
|
3: ldr r3, [r0]
|
|
cmp ip, #2
|
|
mov ip, r3, get_byte_0
|
|
strb ip, [r1], #1
|
|
bgt 6f
|
|
mov ip, r3, get_byte_1
|
|
strb ip, [r1], #1
|
|
beq 5f
|
|
mov ip, r3, get_byte_2
|
|
strb ip, [r1], #1
|
|
|
|
4: subs r2, r2, #1
|
|
mov ip, r3, lspull #24
|
|
ldrne r3, [r0]
|
|
orrne ip, ip, r3, lspush #8
|
|
strne ip, [r1], #4
|
|
bne 4b
|
|
b 8f
|
|
|
|
5: subs r2, r2, #1
|
|
mov ip, r3, lspull #16
|
|
ldrne r3, [r0]
|
|
orrne ip, ip, r3, lspush #16
|
|
strne ip, [r1], #4
|
|
bne 5b
|
|
b 7f
|
|
|
|
6: subs r2, r2, #1
|
|
mov ip, r3, lspull #8
|
|
ldrne r3, [r0]
|
|
orrne ip, ip, r3, lspush #24
|
|
strne ip, [r1], #4
|
|
bne 6b
|
|
|
|
mov r3, ip, get_byte_2
|
|
strb r3, [r1, #2]
|
|
7: mov r3, ip, get_byte_1
|
|
strb r3, [r1, #1]
|
|
8: mov r3, ip, get_byte_0
|
|
strb r3, [r1, #0]
|
|
ret lr
|
|
ENDPROC(__raw_readsl)
|